import org.apache.tools.ant.taskdefs.condition.Os

apply plugin: 'com.android.application'

android {
    compileSdkVersion PROP_COMPILE_SDK_VERSION.toInteger()
    buildToolsVersion PROP_BUILD_TOOLS_VERSION

    defaultConfig {
        applicationId "com.fitchgc.jcwallet"
        minSdkVersion PROP_MIN_SDK_VERSION
        targetSdkVersion PROP_TARGET_SDK_VERSION
        versionCode 1
        versionName "1.0"
        ndk{
            abiFilters 'armeabi-v7a','arm64-v8a', 'x86'
        }

        externalNativeBuild {
            ndkBuild {
                if (!project.hasProperty("PROP_NDK_MODE") || PROP_NDK_MODE.compareTo('none') != 0) {
                    // skip the NDK Build step if PROP_NDK_MODE is none
                    targets 'cocos2djs'
                    arguments 'NDK_TOOLCHAIN_VERSION=clang'

                    def module_paths = [project.file(rootProject.ext.cfgs.cocos2dxBasePath),
                                        project.file(rootProject.ext.cfgs.cocos2dxBasePath+"/cocos"),
                                        project.file(rootProject.ext.cfgs.cocos2dxBasePath+"/external")]
                    if (Os.isFamily(Os.FAMILY_WINDOWS)) {
                        arguments 'NDK_MODULE_PATH=' + module_paths.join(";")
                    }
                    else {
                        arguments 'NDK_MODULE_PATH=' + module_paths.join(':')
                    }

                    arguments '-j' + Runtime.runtime.availableProcessors()
                    abiFilters.addAll(PROP_APP_ABI.split(':').collect{it as String})
                }
            }
        }

        manifestPlaceholders = [
                'appAuthRedirectScheme': 'com.googleusercontent.apps.165555585193-glmtnb94s3kkq906hal72ppiuoqpjjc5'
        ]
    }

    sourceSets.main {
        java.srcDirs "../src", "src"
        res.srcDirs "../res", 'res'
        jniLibs.srcDirs "../libs", 'libs', rootProject.ext.cfgs.unityAndroidProject + '/src/main/jniLibs'
        manifest.srcFile "AndroidManifest.xml"
    }

    externalNativeBuild {
        ndkBuild {
            if (!project.hasProperty("PROP_NDK_MODE") || PROP_NDK_MODE.compareTo('none') != 0) {
                // skip the NDK Build step if PROP_NDK_MODE is none
                path "jni/Android.mk"
            }
        }
    }

    signingConfigs {
        debug {
            storeFile file("${rootDir}/keys/release")
            storePassword '7654321'
            keyAlias 'release'
            keyPassword '7654321'
        }
        release {
            storeFile file("${rootDir}/keys/release")
            storePassword "7654321"
            keyAlias "release"
            keyPassword "7654321"
        }
    }

    buildTypes {
        debug {
            signingConfig signingConfigs.debug
        }
        release {
            minifyEnabled false
            signingConfig signingConfigs.release
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
}

android.applicationVariants.all { variant ->
    // delete previous files first
    delete "${buildDir}/intermediates/merged_assets/${variant.dirName}"

    variant.mergeAssets.doLast {
        def sourceDir = rootProject.ext.cfgs.jsFilePath

        copy{
            from "${sourceDir}"
            include "js/**"
            into outputDir
        }
        copy {
            from "${sourceDir}/cert/cacert.pem"
            into outputDir
        }
        def sourceDirUnity = rootProject.ext.cfgs.unityAndroidProject + "/src/main/assets/"

        copy {
            from "${sourceDirUnity}"
            include "**"
            into outputDir
        }
    }
}


dependencies {

    implementation fileTree(dir: '../libs', include: ['*.jar','*.aar'])
    implementation fileTree(dir: 'libs', include: ['*.jar','*.aar'])
    implementation fileTree(dir: rootProject.ext.cfgs.cocos2dxBasePath + "/cocos/platform/android/java/libs", include: ['*.jar'])
    implementation project(':libcocos2dx')

    implementation "androidx.appcompat:appcompat:1.0.2"
    implementation "androidx.biometric:biometric:1.1.0"

    implementation 'com.google.android.gms:play-services-auth:20.3.0'

//    implementation 'com.xm.permissions:XmPermissions:1.0.1'
    implementation 'pub.devrel:easypermissions:3.0.0'
    implementation 'com.github.jenly1314:zxing-lite:2.1.1'
    implementation project(path: ':libcocos2dx')
    implementation 'net.openid:appauth:0.11.1'
    implementation "com.squareup.okio:okio:2.10.0"
    implementation 'com.android.volley:volley:1.2.1'
    implementation 'org.greenrobot:eventbus:3.0.0'
}